This series will provide answers to the list of Solidity interview questions that were published by RareSkills.
The difference between transferFrom and safeTransferFrom in ERC721 is the callback that safeTransferFrom performs to ensure that the receiver is a safe recipient.
While transferFrom and safeTransferFrom are both used to transfer a token from one account to another, safeTransferFrom checks if the recipient is a contract and if so, it calls a callback function on the recipient, onERC721Received, and reverts if the recipient does not return the magic value (bytes4(keccak256("onERC721Received(address,address,uint256,bytes)")))
See OpenZeppelin’s implementation here:
/**
* @dev See {IERC721-transferFrom}.
*/
function transferFrom(address from, address to, uint256 tokenId) public virtual {
if (to == address(0)) {
revert ERC721InvalidReceiver(address(0));
}
// Setting an "auth" arguments enables the `_isAuthorized` check which verifies that the token exists
// (from != 0). Therefore, it is not needed to verify that the return value is not 0 here.
address previousOwner = _update(to, tokenId, _msgSender());
if (previousOwner != from) {
revert ERC721IncorrectOwner(from, tokenId, previousOwner);
}
}
/**
* @dev See {IERC721-safeTransferFrom}.
*/
function safeTransferFrom(address from, address to, uint256 tokenId) public {
safeTransferFrom(from, to, tokenId, "");
}
/**
* @dev See {IERC721-safeTransferFrom}.
*/
function safeTransferFrom(address from, address to, uint256 tokenId, bytes memory data) public virtual {
transferFrom(from, to, tokenId);
ERC721Utils.checkOnERC721Received(_msgSender(), from, to, tokenId, data);
}
function checkOnERC721Received(
address operator,
address from,
address to,
uint256 tokenId,
bytes memory data
) internal {
if (to.code.length > 0) {
try IERC721Receiver(to).onERC721Received(operator, from, tokenId, data) returns (bytes4 retval) {
if (retval != IERC721Receiver.onERC721Received.selector) {
// Token rejected
revert IERC721Errors.ERC721InvalidReceiver(to);
}
} catch (bytes memory reason) {
if (reason.length == 0) {
// non-IERC721Receiver implementer
revert IERC721Errors.ERC721InvalidReceiver(to);
} else {
/// @solidity memory-safe-assembly
assembly {
revert(add(32, reason), mload(reason))
}
}
}
}
}
The purpose of the “safe” mechanism is to avoid locking the token by transferring to a recipient that cannot execute another transfer. If the recipient returns the expected value then we can be confident that the smart contract has implemented a mechanism to transfer the token in the future.